[VBScript] クリップボードとの文字データのやり取りを実現する

どーもボキです。

VBScriptでも文字列のコピペはカンタン

クリップボードからの文字データ取得、クリップボードへの文字データの反映、これらはVBScriptでもカンタンに実現可能だ。

サンプルプログラムのダウンロードと使い方

• ダウンロード
  
• 使い方は、実行する、だけ。
  クリップボードへ、実行時間と実行ファイル名情報が送る。また、クリップボードから文字データを取得し、ダイアログ表示する（下図）。
  

SetClipboard関数、GetClipboard関数のソース

クリップボードへのコピーは、以下の１行のコードでも実現できる。


CreateObject("WScript.Shell").Exec("clip").StdIn.Write Str

しかし、上記ではクリップボードへのコピー処理が完了しないうちに次の処理へ移る。
このため、WScript.Sleep などで時間調整が必要となることがある。


以下のコードなら、クリップボードへのコピー完了まで待つので、WScript.Sleepなど不要。

'-------------------------------------------------------------------------------
' クリップボードを取得
'-------------------------------------------------------------------------------
Function GetClipboard
    GetClipboard = CreateObject("htmlfile").ParentWindow.ClipboardData.getData("text") & ""
End Function


'-------------------------------------------------------------------------------
' クリップボードにコピー
'-------------------------------------------------------------------------------
Sub SetClipboard(iStr)
    ' 一時ファイルへコピー文字を記載
    Dim objFS
    Set objFS = CreateObject("Scripting.FileSystemObject")
    
    Dim fpth
    Dim dpth_tmp
    dpth_tmp = objFS.GetSpecialFolder(2) & "\"   ' tempフォルダパス
    fpth = dpth_tmp & objFS.GetTempName
    
    Dim tmp
    Set tmp = objFS.CreateTextFile(fpth, True)
    tmp.Write iStr
    tmp.Close
    
    On Error Resume Next    ' 環境依存文字への対応
    
    ' 一時ファイルをクリップボードへ
    cmd = "cmd /c clip < " & fpth 
    CreateObject("WScript.Shell").Run cmd, 0, True
    
    On Error Goto 0
    
    ' 一時ファイルを削除
    objFS.DeleteFile fpth, True
End Sub

この記事での気付き

VBScriptに限らず、必要となる処理をひとつの開発手段だけで実現するのではなく、
複数の開発手段を組み合わせたハイブリットの開発手段を取れると、実現したいことに手早くたどり着ける。

それに気付けるようになるためには、日頃から技術の幅を広げておくことが必要だ。

ファイル・フォルダ操作系ならば、bat、vbs、ps等、OSの基本機能とのハイブリットがオススメ。


チーム運営でもプログラム開発でも、餅は餅屋、ですな。


VBScriptに限らず、こういった処理系を使い分けるという考え方、超重要ですよ。

→ 親子の関係は「上司と部下」。「友達」には決してなるな

にほんブログ村