[VBScript] クリップボードとの文字データのやり取りを実現する

どーもボキです。

2024/5/18更新

ボキが出入りする会社の話になりますが、Win11環境では従来ロジックではGetClipBoard（コピーした文字列を取得する関数）が動かなかったため、PowerShellを利用したものへ修正しました。

VBScriptでも、クリップボードからの文字列の取得、クリップボードへの文字列を反映、どちらもカンタンに実現できます。

サンプルプログラムのダウンロードと使い方

• ダウンロード
  
• 使い方は、実行する、だけ。
  SetClipBoard関数にてクリップボードへ、実行時間と実行ファイル名情報を送り、GetClipBoard関数にてクリップボードより文字データを取得し、ダイアログへ表示します（下図）。
  

SetClipboard関数、GetClipboard関数のソース

クリップボードへのコピーは、以下の１行のコードでも実現できます。


CreateObject("WScript.Shell").Exec("clip").StdIn.Write Str



ただ上記の方法では、clipプロセスの終了待ちをしないため、クリップボードへの文字列反映が完了しないうちに次の処理へ移ってしまうことがあります。これが困るならWScript.Sleepなどを用いたタイミング調整が必要と、若干メンドウなことになります。そして、ボキ的重要ポイント、clipプロセスの実行時に一瞬ウィンドウが表示されてカッコ悪い！


以下のコード（ダウンロード）なら、clipプロセスを非表示で実行し、処理完了まで待たせていますので、WScript.Sleepでの時間調整はいりません。当然、余計なウィンドウはでません。



SetClipboard Now & vbLf & WScript.ScriptName
Dim s
s = GetClipboard
MsgBox s
''-------------------------------------------------------------------------------
'' クリップボードから文字列を取得する
''-------------------------------------------------------------------------------
'Function GetClipboard
'   GetClipboard = CreateObject("htmlfile").ParentWindow.ClipboardData.getData("text") & "" ' 「"」はリッチテキストの変換
'End Function

'-------------------------------------------------------------------------------
' クリップボードから文字列を取得する
'-------------------------------------------------------------------------------
Function GetClipboard
    On Error Resume Next
    Dim r: r = ""
    
    Dim objWS: Set objWS = CreateObject("WScript.Shell")
    Dim objFS: Set objFS = CreateObject("Scripting.FileSystemObject")
    
    Dim fpth
    fpth = objFS.GetSpecialFolder(2) & "\" & objFS.GetTempName
    
    ' クリップボードの内容を一時ファイルへ
    cmd = "cmd /c PowerShell Get-Clipboard -Format Text > " & fpth
    objWS.Run cmd, 0, True
    
    ' 一時ファイルの処理
    If objFS.FileExists(fpth) Then
        r = objFS.OpenTextFile(fpth, 1).ReadAll
        objFS.DeleteFile fpth, True
    End If
    GetClipboard = r
    
    On Error Goto 0
End Function

'-------------------------------------------------------------------------------
' クリップボードへ文字列をコピーする
'-------------------------------------------------------------------------------
Sub SetClipboard(iStr)
    On Error Resume Next
::::Do
    ' 一時ファイルへコピー文字を記載
    Dim objFS
    Set objFS = CreateObject("Scripting.FileSystemObject")
    
    Dim fpth
    fpth = DPath_temp & objFS.GetTempName
    
    Dim tmp
    Set tmp = objFS.CreateTextFile(fpth, True)
    tmp.Write iStr
    tmp.Close
    If Err Then MsgBox "環境依存文字が含まれるためコピーできません。", vbCritical, "SetClipboard": Exit Do
    
    ' 一時ファイルをクリップボードへ
    cmd = "cmd /c clip < " & fpth
    CreateObject("WScript.Shell").Run cmd, 0, True
::::Loop Until 1
    
    ' 一時ファイルを削除
    objFS.DeleteFile fpth, True
    
    On Error Goto 0
End Sub

この記事での気付き

VBScriptに限らず、必要となる処理をひとつの開発手段だけで実現するのではなく、複数の開発手段を組み合わせたハイブリットの開発手段を取れると、実現したいことに手早くたどり着けます。

それに気付けるようになるためには、日頃から技術の幅を広げておくことが必要ですね。

ファイル・フォルダ操作系ならば、bat、vbs、ps等、OSの基本機能とのハイブリット開発をオススメします。


VBScriptに限らず、こういった処理系を使い分けるという考え方、重要ですし、チーム運営でもプログラム開発でも、餅は餅屋、得意を活かすことが重要ですよね。
→ 親子の関係は「上司と部下」。「友達」には決してなるな

にほんブログ村